Configuring Doom Emacs

(defvar my-ssh-config-files
  '("~/.ssh/config"
    "~/.ssh/work"
    "~/.ssh/private")
  "List of SSH config files for TRAMP completion.")

(tramp-set-completion-function
 "ssh"
 (append
  (mapcar (lambda (f)
            (list 'tramp-parse-sconfig (expand-file-name f)))
          my-ssh-config-files)
  '((tramp-parse-sconfig "/etc/ssh_config")
    (tramp-parse-shosts "/etc/hosts")
    (tramp-parse-shosts "~/.ssh/known_hosts"))))

(defun my/open-remote-conn ()
  "Open remote SSH connection with Tramp."
  (interactive)
  (find-file (read-file-name "Pick target: " "/ssh:")))

(setq tramp-use-ssh-controlmaster-options nil)

;; Cache remote file properties longer
(setq remote-file-name-inhibit-cache nil)

;; Disable VC checks on remote files
(setq vc-ignore-dir-regexp
      (format "\\(%s\\)\\|\\(%s\\)"
              vc-ignore-dir-regexp
              tramp-file-name-regexp))

# From remote shell:
$ e .bashrc      # Opens /ssh:user@host:.bashrc in Emacs
$ e src/main.rs  # Relative paths work too

(defun my/vterm-tramp-base-path ()
  "Return the Tramp prefix without the directory."
  (let* ((vec (or (car (tramp-list-connections))
                  (when (tramp-tramp-file-p default-directory)
                    (tramp-dissect-file-name default-directory))))
         (method (and vec (tramp-file-name-method vec)))
         (user   (and vec (tramp-file-name-user vec)))
         (host   (and vec (tramp-file-name-host vec))))
    (when (and method host)
      (format "/%s:%s%s" method
              (if (and user (not (string-empty-p user)))
                  (concat user "@") "")
              host))))

(defun my/vterm-buffer-hooks-on-tramp ()
  "Set up vterm for remote Tramp connections."
  (when (and (eq major-mode 'vterm-mode)
             default-directory
             (file-remote-p default-directory))
    (let ((tramp-base-path (my/vterm-tramp-base-path)))
      (rename-buffer (format "*vterm@%s*" tramp-base-path) t)
      (vterm-send-string
       (format
        "e() { local f=\"$1\"; [[ \"$f\" != /* ]] && f=\"$PWD/$f\"; \
printf '\\033]51;Efind-file %s:%%s\\007' \"$f\"; }\n"
        tramp-base-path)))
    (vterm-send-string "clear\n")))

(add-hook! 'vterm-mode-hook #'my/vterm-buffer-hooks-on-tramp)

(defun my/save-and-close-buffer ()
  "Save, close current buffer and display a confirmation message."
  (interactive)
  (save-buffer)
  (message "Closed and saved: %s" (buffer-name))
  (kill-buffer (current-buffer)))

(defun my/kill-all-buffers-except-current ()
  "Kill all buffers except the current one."
  (interactive)
  (mapc 'my/kill-buffer (delete (current-buffer) (buffer-list)))
  (message "Killed all buffers except: %s" (current-buffer)))

(defun my/insert-timestamp (&optional datetime)
  "Insert current date or date+time."
  (interactive "P")
  (let ((fmt (if datetime "%Y-%m-%d %H:%M" "%Y-%m-%d")))
    (insert (format-time-string fmt))))

(defun my/insert-email ()
  "Insert an email address from `my-email-addresses-alist'."
  (interactive)
  (let* ((keys (mapcar #'car my-email-addresses-alist))
         (choice (completing-read "Email: " keys nil t)))
    (insert (my/get-email choice))))

(defun my/fuzzy-kill-process ()
  "Fuzzy-pick a system process and send SIGKILL."
  (interactive)
  (let* ((fmt-item
          (lambda (pid)
            (let ((a (process-attributes pid)))
              (when a
                (let* ((name (alist-get 'comm a))
                       (pcpu (or (alist-get 'pcpu a) 0.0))
                       (rss  (alist-get 'rss a))
                       (rss-mb (if (numberp rss) (/ rss 1024.0) 0.0)))
                  (cons (format "%-20s %6d  %7.1fMB  %5.1f%%"
                                (or name "?") pid rss-mb pcpu)
                        pid))))))
         (items (delq nil (mapcar fmt-item (list-system-processes))))
         (choice (completing-read "Kill process: " (mapcar #'car items) nil t))
         (pid (cdr (assoc choice items))))
    (signal-process pid 'kill)
    (message "Killed: %s" choice)))

(defun my/find-file-in-dotfiles ()
  "Find file in my dotfiles."
  (interactive)
  (doom-project-find-file my-dotfiles-dir))

(defun my/where-am-i ()
  "Display the current buffer's file path or buffer name."
  (interactive)
  (message (if (buffer-file-name)
               (buffer-file-name)
             (concat "buffer-name=" (buffer-name)))))

(defun my/vertico-search-project-symbol-at-point (&optional arg)
  "Performs a live project search for the thing at point."
  (interactive)
  (+vertico/project-search arg (thing-at-point 'symbol)))

(defun my/scroll-up ()
  "Scroll view up by 3 lines."
  (interactive)
  (scroll-down 3))

(defun my/scroll-down ()
  "Scroll view down by 3 lines."
  (interactive)
  (scroll-up 3))

(defun my/enlarge-window-horizontally ()
  "Enlarge window horizontally by 5 columns."
  (interactive)
  (enlarge-window-horizontally 5))

(when (and (daemonp) (eq system-type 'gnu/linux))
  (defun my/update-wayland-env-from-frame ()
    "Update WAYLAND_DISPLAY and SWAYSOCK from the current frame."
    (when-let ((runtime-dir (getenv "XDG_RUNTIME_DIR")))
      (when (directory-files runtime-dir nil "^sway-ipc\\..*\\.sock$")
        (dolist (var '("WAYLAND_DISPLAY" "SWAYSOCK"))
          (when-let ((val (getenv var (selected-frame))))
            (setenv var val))))))
  (add-hook! 'server-after-make-frame-hook
             #'my/update-wayland-env-from-frame))

(disable-packages!
 lsp-python-ms  ; prefer basedpyright
 pipenv         ; prefer poetry
 nose           ; prefer pytest
 lsp-ui         ; prefer eglot's minimal approach
 solaire-mode   ; interferes with my theme
 evil-escape)   ; not needed with my custom keyboard

(define-abbrev-table 'python-mode-abbrev-table
  '(("ifn" "if __name__ == \"__main__\":\n    " nil 0)
    ("pdb" "import pdb; pdb.set_trace()  # debug" nil 0)
    ("shb" "#!/usr/bin/env python3\n" nil 0)))

(defun my/kill-buffer (&optional buffer)
  "Kill current buffer without prompts for term/vterm/eshell."
  (interactive)
  (let ((buf (or buffer (current-buffer))))
    (with-current-buffer buf
      (when (derived-mode-p 'vterm-mode 'term-mode 'eshell-mode)
        (set-buffer-modified-p nil)
        (when-let ((proc (get-buffer-process buf)))
          (set-process-query-on-exit-flag proc nil))))
    (kill-buffer buf)))

(package! creamy-theme)
(package! simplicity-theme)